Press n or j to go to the next uncovered block, b, p or k for the previous block.
| 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 | 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x | CLASS zcl_abapgit_file_deserialize DEFINITION
PUBLIC
CREATE PUBLIC .
PUBLIC SECTION.
CLASS-METHODS get_results
IMPORTING
!io_repo TYPE REF TO zcl_abapgit_repo
!ii_log TYPE REF TO zif_abapgit_log OPTIONAL
RETURNING
VALUE(rt_results) TYPE zif_abapgit_definitions=>ty_results_tt
RAISING
zcx_abapgit_exception .
PROTECTED SECTION.
PRIVATE SECTION.
CLASS-METHODS filter_files_to_deserialize
IMPORTING
!it_results TYPE zif_abapgit_definitions=>ty_results_tt
!ii_log TYPE REF TO zif_abapgit_log OPTIONAL
RETURNING
VALUE(rt_results) TYPE zif_abapgit_definitions=>ty_results_tt .
CLASS-METHODS prioritize_deser
IMPORTING
!ii_log TYPE REF TO zif_abapgit_log
!it_results TYPE zif_abapgit_definitions=>ty_results_tt
RETURNING
VALUE(rt_results) TYPE zif_abapgit_definitions=>ty_results_tt .
CLASS-METHODS map_results_to_items
IMPORTING
!it_results TYPE zif_abapgit_definitions=>ty_results_tt
RETURNING
VALUE(rt_items) TYPE zif_abapgit_definitions=>ty_items_tt .
ENDCLASS.
CLASS zcl_abapgit_file_deserialize IMPLEMENTATION.
METHOD filter_files_to_deserialize.
DATA lt_objects LIKE rt_results.
DATA lr_object TYPE REF TO zif_abapgit_definitions=>ty_result.
DATA ls_item TYPE zif_abapgit_definitions=>ty_item.
DATA lv_tabix TYPE sy-tabix.
rt_results = it_results.
"preparation for object logging, sort all file entries by objects
IF ii_log IS BOUND.
lt_objects = rt_results.
SORT lt_objects
BY obj_type
obj_name.
DELETE ADJACENT DUPLICATES FROM lt_objects COMPARING obj_type obj_name.
DELETE lt_objects WHERE obj_type IS INITIAL AND obj_name IS INITIAL.
ENDIF.
"ignore objects w/o changes
DELETE rt_results WHERE match = abap_true. " Full match
"log objects w/o changes
IF sy-subrc = 0 AND ii_log IS BOUND.
SORT rt_results BY obj_type obj_name.
LOOP AT lt_objects REFERENCE INTO lr_object.
lv_tabix = sy-tabix.
READ TABLE rt_results WITH KEY obj_type = lr_object->obj_type
obj_name = lr_object->obj_name
BINARY SEARCH TRANSPORTING NO FIELDS.
IF sy-subrc <> 0.
"all parts of the objects have not changed
ls_item-devclass = lr_object->package.
ls_item-obj_type = lr_object->obj_type.
ls_item-obj_name = lr_object->obj_name.
ii_log->add_success(
iv_msg = |Object { ls_item-obj_name } (type { ls_item-obj_type }) not changed; no import required|
is_item = ls_item ).
"ignore object for further messages
DELETE lt_objects INDEX lv_tabix.
ENDIF.
ENDLOOP.
ENDIF.
"ignore objects w/o object type
DELETE rt_results WHERE obj_type IS INITIAL.
"log objects w/o object type
IF sy-subrc = 0 AND ii_log IS BOUND.
" Note: Moving the CHECK condition to the LOOP WHERE clause will lead to a
" syntax warning in higher releases and syntax error in 702
LOOP AT lt_objects REFERENCE INTO lr_object.
CHECK lr_object->obj_type IS INITIAL AND lr_object->obj_name IS NOT INITIAL.
ls_item-devclass = lr_object->package.
ls_item-obj_type = lr_object->obj_type.
ls_item-obj_name = lr_object->obj_name.
ii_log->add_warning(
iv_msg = |Object type for { ls_item-obj_name } not defined - will be ignored by abapGit|
is_item = ls_item ).
ENDLOOP.
DELETE lt_objects WHERE obj_type IS INITIAL.
ENDIF.
"ignore objects that exists only local
DELETE rt_results WHERE lstate = zif_abapgit_definitions=>c_state-added AND rstate IS INITIAL.
"ignore objects that where deleted remotely
DELETE rt_results WHERE rstate = zif_abapgit_definitions=>c_state-deleted.
"log objects that exists only local or where deleted remotely
IF sy-subrc = 0 AND ii_log IS BOUND.
SORT rt_results BY obj_type obj_name.
LOOP AT lt_objects REFERENCE INTO lr_object.
lv_tabix = sy-tabix.
READ TABLE rt_results WITH KEY obj_type = lr_object->obj_type
obj_name = lr_object->obj_name
BINARY SEARCH TRANSPORTING NO FIELDS.
IF sy-subrc <> 0.
"all parts exists only local
"no log message; ignore object for further messages
DELETE lt_objects INDEX lv_tabix.
ENDIF.
ENDLOOP.
ENDIF.
"ignore table content
DELETE rt_results WHERE path = zif_abapgit_data_config=>c_default_path.
SORT rt_results
BY obj_type ASCENDING
obj_name ASCENDING
rstate DESCENDING " ensures that non-empty rstate is kept
lstate DESCENDING. " ensures that non-empty lstate is kept
DELETE ADJACENT DUPLICATES FROM rt_results COMPARING obj_type obj_name.
ENDMETHOD.
METHOD get_results.
DATA lt_results TYPE zif_abapgit_definitions=>ty_results_tt.
lt_results = filter_files_to_deserialize(
it_results = zcl_abapgit_repo_status=>calculate( io_repo )
ii_log = ii_log ).
rt_results = prioritize_deser(
ii_log = ii_log
it_results = lt_results ).
ENDMETHOD.
METHOD map_results_to_items.
DATA ls_item LIKE LINE OF rt_items.
FIELD-SYMBOLS: <ls_result> TYPE zif_abapgit_definitions=>ty_result.
LOOP AT it_results ASSIGNING <ls_result>.
ls_item-devclass = <ls_result>-package.
ls_item-obj_type = <ls_result>-obj_type.
ls_item-obj_name = <ls_result>-obj_name.
INSERT ls_item INTO TABLE rt_items.
ENDLOOP.
ENDMETHOD.
METHOD prioritize_deser.
DATA lt_items TYPE zif_abapgit_definitions=>ty_items_tt.
DATA ls_item LIKE LINE OF lt_items.
DATA lt_requires TYPE zif_abapgit_definitions=>ty_items_tt.
DATA ls_require LIKE LINE OF lt_requires.
DATA ls_result LIKE LINE OF it_results.
DATA lo_graph TYPE REF TO zcl_abapgit_item_graph.
lt_items = map_results_to_items( it_results ).
CREATE OBJECT lo_graph EXPORTING it_items = lt_items.
LOOP AT lt_items INTO ls_item.
CLEAR lt_requires.
* TODO: BEGIN extract to object handler method in ZIF_ABAPGIT_OBJECT:
* METHODS get_deserialize_order
* IMPORTING
* it_items TYPE ty_items_tt
* RETURNING
* VALUE(rt_requries) TYPE ty_items_tt
CASE ls_item-obj_type.
WHEN 'SPRX'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'WEBI'.
WHEN 'CLAS'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'SPRX'
AND obj_type <> 'INTF'
AND obj_type <> 'XSLT'.
WHEN 'PROG'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'XSLT'.
WHEN 'INTF'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'SPRX'
AND obj_type <> 'XSLT'.
WHEN 'TABL'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'SPRX'.
WHEN 'IARP'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'IASP'.
WHEN 'IATU' OR 'IAXU' OR 'IAMU'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'IASP'
AND obj_type <> 'PROG'
AND obj_type <> 'IARP'.
WHEN 'DCLS'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'DDLS'.
WHEN 'ODSO'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'IOBJ'.
WHEN 'SCP1'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'TOBJ'.
WHEN 'CHAR'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'OTGR'.
WHEN 'PINF'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'CLAS'
AND obj_type <> 'INTF'
AND obj_type <> 'TABL'
AND obj_type <> 'DOMA'
AND obj_type <> 'DTEL'.
WHEN 'DEVC'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'PINF'.
WHEN 'ENHC'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'ENHO'.
WHEN 'ENHO'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'ENSC' AND obj_type <> 'ENHS'.
WHEN 'ENSC'.
lt_requires = lt_items.
DELETE lt_requires WHERE obj_type <> 'ENHS'.
ENDCASE.
* TODO: END extract to object handler method
LOOP AT lt_requires INTO ls_require.
lo_graph->add_edge(
is_from = ls_require
is_to = ls_item ).
ENDLOOP.
ENDLOOP.
WHILE lo_graph->has_vertices( ) = abap_true.
ls_item = lo_graph->get_next( ii_log ).
READ TABLE it_results INTO ls_result WITH KEY sec_key COMPONENTS
obj_name = ls_item-obj_name
obj_type = ls_item-obj_type.
ASSERT sy-subrc = 0.
APPEND ls_result TO rt_results.
ENDWHILE.
ENDMETHOD.
ENDCLASS.
|