Press n or j to go to the next uncovered block, b, p or k for the previous block.
| 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 | 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x | CLASS zcl_abapgit_object_dtel DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
PUBLIC SECTION.
INTERFACES zif_abapgit_object.
METHODS constructor
IMPORTING
is_item TYPE zif_abapgit_definitions=>ty_item
iv_language TYPE spras
io_files TYPE REF TO zcl_abapgit_objects_files OPTIONAL
io_i18n_params TYPE REF TO zcl_abapgit_i18n_params OPTIONAL
RAISING
zcx_abapgit_exception.
PROTECTED SECTION.
PRIVATE SECTION.
DATA mv_aff_enabled TYPE abap_bool.
TYPES:
BEGIN OF ty_dd04_text,
ddlanguage TYPE dd04t-ddlanguage,
ddtext TYPE dd04t-ddtext,
reptext TYPE dd04t-reptext,
scrtext_s TYPE dd04t-scrtext_s,
scrtext_m TYPE dd04t-scrtext_m,
scrtext_l TYPE dd04t-scrtext_l,
END OF ty_dd04_text .
TYPES:
ty_dd04_texts TYPE STANDARD TABLE OF ty_dd04_text .
" Fields that are not part of dd04v
TYPES:
BEGIN OF ty_extra,
abap_language_version TYPE uccheck,
END OF ty_extra.
CONSTANTS c_longtext_id_dtel TYPE dokil-id VALUE 'DE' ##NO_TEXT.
CONSTANTS c_longtext_id_dtel_suppl TYPE dokil-id VALUE 'DZ' ##NO_TEXT.
METHODS delete_documentation
RAISING
zcx_abapgit_exception.
METHODS serialize_texts
IMPORTING
!ii_xml TYPE REF TO zif_abapgit_xml_output
RAISING
zcx_abapgit_exception .
METHODS deserialize_texts
IMPORTING
!ii_xml TYPE REF TO zif_abapgit_xml_input
!is_dd04v TYPE dd04v
RAISING
zcx_abapgit_exception .
ENDCLASS.
CLASS zcl_abapgit_object_dtel IMPLEMENTATION.
METHOD constructor.
super->constructor(
is_item = is_item
iv_language = iv_language
io_files = io_files
io_i18n_params = io_i18n_params ).
mv_aff_enabled = zcl_abapgit_aff_factory=>get_registry( )->is_supported_object_type( 'DTEL' ).
ENDMETHOD.
METHOD delete_documentation.
delete_longtexts( c_longtext_id_dtel ).
delete_longtexts( c_longtext_id_dtel_suppl ).
ENDMETHOD.
METHOD deserialize_texts.
DATA: lv_name TYPE ddobjname,
ls_dd04v_tmp TYPE dd04v,
lt_i18n_langs TYPE TABLE OF langu,
lt_dd04_texts TYPE ty_dd04_texts.
FIELD-SYMBOLS: <lv_lang> LIKE LINE OF lt_i18n_langs,
<ls_dd04_text> LIKE LINE OF lt_dd04_texts.
lv_name = ms_item-obj_name.
ii_xml->read( EXPORTING iv_name = 'I18N_LANGS'
CHANGING cg_data = lt_i18n_langs ).
ii_xml->read( EXPORTING iv_name = 'DD04_TEXTS'
CHANGING cg_data = lt_dd04_texts ).
mo_i18n_params->trim_saplang_list( CHANGING ct_sap_langs = lt_i18n_langs ).
SORT lt_i18n_langs.
SORT lt_dd04_texts BY ddlanguage. " Optimization
LOOP AT lt_i18n_langs ASSIGNING <lv_lang>.
" Data element description
ls_dd04v_tmp = is_dd04v.
READ TABLE lt_dd04_texts ASSIGNING <ls_dd04_text> WITH KEY ddlanguage = <lv_lang>.
IF sy-subrc > 0.
zcx_abapgit_exception=>raise( |DD04_TEXTS cannot find lang { <lv_lang> } in XML| ).
ENDIF.
MOVE-CORRESPONDING <ls_dd04_text> TO ls_dd04v_tmp.
CALL FUNCTION 'DDIF_DTEL_PUT'
EXPORTING
name = lv_name
dd04v_wa = ls_dd04v_tmp
EXCEPTIONS
dtel_not_found = 1
name_inconsistent = 2
dtel_inconsistent = 3
put_failure = 4
put_refused = 5
OTHERS = 6.
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise_t100( ).
ENDIF.
ENDLOOP.
ENDMETHOD.
METHOD serialize_texts.
DATA: lv_name TYPE ddobjname,
lv_index TYPE i,
ls_dd04v TYPE dd04v,
lt_dd04_texts TYPE ty_dd04_texts,
lt_i18n_langs TYPE TABLE OF langu,
lt_language_filter TYPE zif_abapgit_environment=>ty_system_language_filter.
FIELD-SYMBOLS: <lv_lang> LIKE LINE OF lt_i18n_langs,
<ls_dd04_text> LIKE LINE OF lt_dd04_texts.
IF mo_i18n_params->ms_params-main_language_only = abap_true.
RETURN.
ENDIF.
lv_name = ms_item-obj_name.
" Collect additional languages, skip main lang - it was serialized already
lt_language_filter = mo_i18n_params->build_language_filter( ).
SELECT DISTINCT ddlanguage AS langu INTO TABLE lt_i18n_langs
FROM dd04v
WHERE rollname = lv_name
AND ddlanguage IN lt_language_filter
AND ddlanguage <> mv_language
ORDER BY langu. "#EC CI_SUBRC
LOOP AT lt_i18n_langs ASSIGNING <lv_lang>.
lv_index = sy-tabix.
CALL FUNCTION 'DDIF_DTEL_GET'
EXPORTING
name = lv_name
langu = <lv_lang>
IMPORTING
dd04v_wa = ls_dd04v
EXCEPTIONS
illegal_input = 1
OTHERS = 2.
IF sy-subrc <> 0 OR ls_dd04v-ddlanguage IS INITIAL.
DELETE lt_i18n_langs INDEX lv_index. " Don't save this lang
CONTINUE.
ENDIF.
APPEND INITIAL LINE TO lt_dd04_texts ASSIGNING <ls_dd04_text>.
MOVE-CORRESPONDING ls_dd04v TO <ls_dd04_text>.
ENDLOOP.
SORT lt_i18n_langs ASCENDING.
SORT lt_dd04_texts BY ddlanguage ASCENDING.
ii_xml->add( iv_name = 'I18N_LANGS'
ig_data = lt_i18n_langs ).
ii_xml->add( iv_name = 'DD04_TEXTS'
ig_data = lt_dd04_texts ).
ENDMETHOD.
METHOD zif_abapgit_object~changed_by.
SELECT SINGLE as4user FROM dd04l INTO rv_user
WHERE rollname = ms_item-obj_name
AND as4local = 'A'
AND as4vers = '0000'.
IF sy-subrc <> 0.
rv_user = c_user_unknown.
ENDIF.
ENDMETHOD.
METHOD zif_abapgit_object~delete.
IF zif_abapgit_object~exists( ) = abap_false.
RETURN.
ENDIF.
delete_ddic( 'E' ).
delete_documentation( ).
ENDMETHOD.
METHOD zif_abapgit_object~deserialize.
DATA: ls_dd04v TYPE dd04v,
ls_extra TYPE ty_extra,
lv_name TYPE ddobjname,
lv_json TYPE xstring,
lv_using_aff TYPE abap_bool.
" The format is determined by the files of the repository, not by mv_aff_enabled:
" there is no XML to fall back to when a JSON file is present
lv_using_aff = mo_files->contains_file( 'json' ).
IF lv_using_aff = abap_true.
lv_json = mo_files->read_raw( 'json' ).
lcl_aff_metadata_handler=>deserialize(
EXPORTING
iv_json = lv_json
iv_object_name = ms_item-obj_name
it_files = mo_files->get_files( )
IMPORTING
es_dd04v = ls_dd04v
ev_abap_language_version = ls_extra-abap_language_version ).
ELSE.
io_xml->read( EXPORTING iv_name = 'DD04V'
CHANGING cg_data = ls_dd04v ).
ENDIF.
IF ls_dd04v-ddtext IS INITIAL.
zcx_abapgit_exception=>raise( |DTEL { ms_item-obj_name }: description is empty| ).
ENDIF.
corr_insert( iv_package = iv_package
ig_object_class = 'DICT' ).
lv_name = ms_item-obj_name. " type conversion
CALL FUNCTION 'DDIF_DTEL_PUT'
EXPORTING
name = lv_name
dd04v_wa = ls_dd04v
EXCEPTIONS
dtel_not_found = 1
name_inconsistent = 2
dtel_inconsistent = 3
put_failure = 4
put_refused = 5
OTHERS = 6.
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise_t100( ).
ENDIF.
IF lv_using_aff = abap_false.
" Fields that are not part of dd04v
io_xml->read( EXPORTING iv_name = 'DD04L_EXTRA'
CHANGING cg_data = ls_extra ).
ENDIF.
TRY.
set_abap_language_version( CHANGING cv_abap_language_version = ls_extra-abap_language_version ).
UPDATE ('DD04L') SET abap_language_version = ls_extra-abap_language_version WHERE rollname = lv_name.
CATCH cx_sy_dynamic_osql_semantics ##NO_HANDLER.
ENDTRY.
IF lv_using_aff = abap_true.
" Note: The AFF format has no representation for the supplementary
" documentation (c_longtext_id_dtel_suppl) and for translations
deserialize_longtexts_aff( c_longtext_id_dtel ).
ELSE.
IF mo_i18n_params->is_lxe_applicable( ) = abap_false.
deserialize_texts(
ii_xml = io_xml
is_dd04v = ls_dd04v ).
ENDIF.
deserialize_longtexts( ii_xml = io_xml
iv_longtext_id = c_longtext_id_dtel ).
deserialize_longtexts( ii_xml = io_xml
iv_longtext_name = 'LONGTEXTS_' && c_longtext_id_dtel_suppl
iv_longtext_id = c_longtext_id_dtel_suppl ).
ENDIF.
zcl_abapgit_objects_activation=>add_item( ms_item ).
ENDMETHOD.
METHOD zif_abapgit_object~exists.
DATA lv_rollname TYPE dd04l-rollname.
DATA ls_x030l TYPE x030l.
lv_rollname = ms_item-obj_name.
" Check nametab because it's fast
CALL FUNCTION 'DD_GET_NAMETAB_HEADER'
EXPORTING
tabname = lv_rollname
IMPORTING
x030l_wa = ls_x030l
EXCEPTIONS
not_found = 1
OTHERS = 2.
IF sy-subrc = 0 AND ls_x030l-tabtype <> 'E'.
" then its not a data element
rv_bool = abap_false.
RETURN.
ELSEIF sy-subrc <> 0.
" Check for inactive or modified versions
SELECT SINGLE rollname FROM dd04l INTO lv_rollname
WHERE rollname = lv_rollname. "#EC CI_NOORDER
ENDIF.
rv_bool = boolc( sy-subrc = 0 ).
ENDMETHOD.
METHOD zif_abapgit_object~get_comparator.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~get_deserialize_order.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~get_deserialize_steps.
APPEND zif_abapgit_object=>gc_step_id-ddic TO rt_steps.
APPEND zif_abapgit_object=>gc_step_id-lxe TO rt_steps.
ENDMETHOD.
METHOD zif_abapgit_object~get_metadata.
rs_metadata = get_metadata( ).
ENDMETHOD.
METHOD zif_abapgit_object~is_active.
rv_active = is_active( ).
ENDMETHOD.
METHOD zif_abapgit_object~is_locked.
rv_is_locked = exists_a_lock_entry_for( iv_lock_object = 'ESDICT'
iv_argument = |{ ms_item-obj_type }{ ms_item-obj_name }| ).
ENDMETHOD.
METHOD zif_abapgit_object~jump.
" Covered by ZCL_ABAPGIT_OBJECT=>JUMP
ENDMETHOD.
METHOD zif_abapgit_object~map_filename_to_object.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~map_object_to_filename.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~serialize.
* fm DDIF_DTEL_GET bypasses buffer, so SELECTs are
* done directly from here
DATA: lv_name TYPE ddobjname,
ls_extra TYPE ty_extra,
ls_dd04v TYPE dd04v,
lv_json TYPE xstring.
FIELD-SYMBOLS <lg_field> TYPE any.
lv_name = ms_item-obj_name.
SELECT SINGLE * FROM dd04l
INTO CORRESPONDING FIELDS OF ls_dd04v
WHERE rollname = lv_name
AND as4local = 'A'
AND as4vers = '0000'.
IF sy-subrc <> 0 OR ls_dd04v IS INITIAL.
IF mv_aff_enabled = abap_true.
" Keep the metadata format consistent for inactive DTELs
mo_files->add_raw(
iv_ext = 'json'
iv_data = zcl_abapgit_convert=>string_to_xstring_utf8( '{}' ) ).
ENDIF.
RETURN.
ENDIF.
SELECT SINGLE * FROM dd04t
INTO CORRESPONDING FIELDS OF ls_dd04v
WHERE rollname = lv_name
AND ddlanguage = mv_language
AND as4local = 'A'
AND as4vers = '0000'.
CLEAR: ls_dd04v-as4user,
ls_dd04v-as4date,
ls_dd04v-as4time.
IF ls_dd04v-refkind = 'D'.
* clear values inherited from domain
CLEAR: ls_dd04v-datatype,
ls_dd04v-leng,
ls_dd04v-decimals,
ls_dd04v-outputlen,
ls_dd04v-valexi,
ls_dd04v-lowercase,
ls_dd04v-signflag,
ls_dd04v-convexit,
ls_dd04v-entitytab.
ENDIF.
ASSIGN COMPONENT 'ACTFLAG' OF STRUCTURE ls_dd04v TO <lg_field>.
IF sy-subrc = 0.
CLEAR <lg_field>.
ENDIF.
ASSIGN COMPONENT 'RESERVEDTE' OF STRUCTURE ls_dd04v TO <lg_field>.
IF sy-subrc = 0.
CLEAR <lg_field>.
ENDIF.
IF ls_dd04v-routputlen = ''.
* numeric field, make sure it is initial or XML serialization will dump
CLEAR ls_dd04v-routputlen.
ENDIF.
IF ls_dd04v-authclass = ''.
CLEAR ls_dd04v-authclass.
ENDIF.
ls_extra-abap_language_version = get_abap_language_version( ).
IF mv_aff_enabled = abap_true.
lv_json = lcl_aff_metadata_handler=>serialize(
is_dd04v = ls_dd04v
iv_abap_language_version = ls_extra-abap_language_version ).
mo_files->add_raw(
iv_ext = 'json'
iv_data = lv_json ).
" Note: The AFF format has no representation for the supplementary
" documentation (c_longtext_id_dtel_suppl) and for translations
serialize_longtexts_aff( iv_longtext_id = c_longtext_id_dtel ).
ELSE.
io_xml->add( iv_name = 'DD04V'
ig_data = ls_dd04v ).
io_xml->add( iv_name = 'DD04L_EXTRA'
ig_data = ls_extra ).
IF mo_i18n_params->is_lxe_applicable( ) = abap_false.
serialize_texts( io_xml ).
ENDIF.
serialize_longtexts( ii_xml = io_xml
iv_longtext_id = c_longtext_id_dtel ).
serialize_longtexts( ii_xml = io_xml
iv_longtext_name = 'LONGTEXTS_' && c_longtext_id_dtel_suppl
iv_longtext_id = c_longtext_id_dtel_suppl ).
ENDIF.
ENDMETHOD.
ENDCLASS.
|