Press n or j to go to the next uncovered block, b, p or k for the previous block.
| 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 | 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 5x 5x 5x 5x 25x 25x 25x 25x 25x 25x 20x 20x 25x 25x 25x 5x 5x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 5x 5x 5x 5x 25x 25x 25x 25x 25x 25x 25x 5x 5x 5x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x | CLASS zcl_abapgit_object_sfpf DEFINITION
PUBLIC
INHERITING FROM zcl_abapgit_objects_super
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
INTERFACES zif_abapgit_object .
CLASS-METHODS fix_oref
IMPORTING
!ii_document TYPE REF TO if_ixml_document
RAISING
zcx_abapgit_exception .
PROTECTED SECTION.
PRIVATE SECTION.
CONSTANTS c_layout_file_ext TYPE string VALUE 'xdp'.
TYPES:
BEGIN OF ty_xml_field,
name TYPE string,
value TYPE string,
END OF ty_xml_field,
ty_xml_fields TYPE STANDARD TABLE OF ty_xml_field WITH DEFAULT KEY,
BEGIN OF ty_context,
name TYPE string,
state TYPE string,
language TYPE string,
id TYPE string,
fields TYPE ty_xml_fields,
END OF ty_context,
ty_contexts TYPE STANDARD TABLE OF ty_context WITH DEFAULT KEY.
CLASS-METHODS sort_contexts
IMPORTING
!ii_document TYPE REF TO if_ixml_document .
METHODS:
check_ads_connection
RAISING
zcx_abapgit_exception,
load
RETURNING VALUE(ri_wb_form) TYPE REF TO if_fp_wb_form
RAISING zcx_abapgit_exception,
form_to_xstring
RETURNING VALUE(rv_xstr) TYPE xstring
RAISING zcx_abapgit_exception.
ENDCLASS.
CLASS zcl_abapgit_object_sfpf IMPLEMENTATION.
METHOD fix_oref.
* During serialization of a SFPF / SFPI object the interface hierarchy
* is represented by attributes "id" and "href", where the id looks
* like "o<number>" and href like "#o<number>". Every run of
* serialization generates a new <number> in these attributes, that
* leads to differences even by comparing of untouched forms.
* The purpose of this method is to renumber the id's consequentially
* and therefore to avoid fictive differences.
* NB: As the method iterator->get_next() works quite slowly,
* it is better to collect all attributes in a cache table
* instead of implementing of a nested loop using get_next().
DATA:
li_iterator TYPE REF TO if_ixml_node_iterator,
li_elem TYPE REF TO if_ixml_element,
lv_new TYPE string,
lv_old TYPE string,
lv_count TYPE i,
BEGIN OF ls_attr_href,
val TYPE string,
attr TYPE REF TO if_ixml_attribute,
END OF ls_attr_href,
lt_attr_href LIKE SORTED TABLE OF ls_attr_href WITH NON-UNIQUE KEY val.
FIELD-SYMBOLS <ls_attr_href> LIKE LINE OF lt_attr_href.
* Collect all attributes href='#o...' in the cache table
li_iterator = ii_document->create_iterator_filtered(
ii_document->create_filter_and(
filter1 = ii_document->create_filter_node_type( if_ixml_node=>co_node_element )
filter2 = ii_document->create_filter_attribute( 'href' ) ) ).
li_elem ?= li_iterator->get_next( ).
WHILE li_elem IS NOT INITIAL.
ls_attr_href-attr = li_elem->get_attribute_node( 'href' ).
ls_attr_href-val = ls_attr_href-attr->get_value( ).
IF ls_attr_href-val CP '##o*'.
INSERT ls_attr_href INTO TABLE lt_attr_href.
ENDIF.
li_elem ?= li_iterator->get_next( ).
ENDWHILE.
* Renumber id='o...' attributes
li_iterator = ii_document->create_iterator_filtered(
ii_document->create_filter_and(
filter1 = ii_document->create_filter_node_type( if_ixml_node=>co_node_element )
filter2 = ii_document->create_filter_attribute( 'id' ) ) ).
li_elem ?= li_iterator->get_next( ).
WHILE li_elem IS NOT INITIAL.
lv_old = li_elem->get_attribute( 'id' ).
IF lv_old CP 'o*'.
lv_count = lv_count + 1.
lv_new = |o{ lv_count }|.
* Rewrite id
IF li_elem->set_attribute( name = 'id'
value = lv_new ) IS NOT INITIAL.
zcx_abapgit_exception=>raise( 'SFPF error, FIX_OREF' ).
ENDIF.
* Update references
LOOP AT lt_attr_href ASSIGNING <ls_attr_href> WHERE val = '#' && lv_old.
IF <ls_attr_href>-attr->set_value( '#' && lv_new ) IS NOT INITIAL.
zcx_abapgit_exception=>raise( 'SFPF error, FIX_OREF' ).
ENDIF.
ENDLOOP.
ENDIF.
li_elem ?= li_iterator->get_next( ).
ENDWHILE.
ENDMETHOD.
METHOD form_to_xstring.
CONSTANTS: lc_empty_data TYPE xstring VALUE ''.
DATA: li_fp_form TYPE REF TO if_fp_form,
li_wb_form TYPE REF TO if_fp_wb_form,
li_fp_layout TYPE REF TO if_fp_layout,
lx_fp_err TYPE REF TO cx_fp_api,
lx_fp_conv_err TYPE REF TO cx_fp_api,
lv_layout_data TYPE xstring.
li_wb_form = load( ).
li_fp_form ?= li_wb_form->get_object( ).
li_fp_layout = li_fp_form->get_layout( ).
lv_layout_data = li_fp_layout->get_layout_data( ).
mo_files->add_raw(
iv_ext = c_layout_file_ext
iv_data = lv_layout_data ).
TRY.
li_fp_layout->set_layout_data( i_layout_data = lc_empty_data
i_set_xliff_ids = abap_false ).
CATCH cx_fp_api INTO lx_fp_err.
zcx_abapgit_exception=>raise( |SFPF remove layout: { lx_fp_err->get_text( ) }| ).
ENDTRY.
TRY.
rv_xstr = cl_fp_helper=>convert_form_to_xstring( li_fp_form ).
CATCH cx_fp_api INTO lx_fp_conv_err ##NO_HANDLER.
" Pass - the exception is handled below!
ENDTRY.
TRY.
li_fp_layout->set_layout_data( i_layout_data = lv_layout_data
i_set_xliff_ids = abap_false ).
CATCH cx_fp_api INTO lx_fp_err.
" Be aware that there might be another exception
" raised by cl_fp_helper=>convert_form_to_xstring( )
zcx_abapgit_exception=>raise( |SFPF recover layout: { lx_fp_err->get_text( ) }| ).
ENDTRY.
IF lx_fp_conv_err IS BOUND.
" This statement handles the exception raised from cl_fp_helper=>convert_form_to_xstring( )
zcx_abapgit_exception=>raise( |SFPF convert_form_to_xstring: { lx_fp_conv_err->get_text( ) }| ).
ENDIF.
ENDMETHOD.
METHOD load.
DATA: lv_name TYPE fpname.
lv_name = ms_item-obj_name.
TRY.
ri_wb_form = cl_fp_wb_form=>load( lv_name ).
CATCH cx_fp_api.
zcx_abapgit_exception=>raise( 'SFPF error, load' ).
ENDTRY.
ENDMETHOD.
METHOD sort_contexts.
DATA: li_node TYPE REF TO if_ixml_node,
li_item TYPE REF TO if_ixml_node,
li_field TYPE REF TO if_ixml_node,
li_item_list TYPE REF TO if_ixml_node_list,
li_iterator TYPE REF TO if_ixml_node_iterator,
li_items TYPE REF TO if_ixml_node_iterator,
lv_index TYPE i,
ls_context TYPE ty_context,
ls_field TYPE ty_xml_field,
lt_contexts TYPE ty_contexts,
li_node_collection TYPE REF TO if_ixml_node_collection.
FIELD-SYMBOLS: <ls_field> TYPE ty_xml_field,
<lv_value> TYPE any.
li_node_collection = ii_document->get_elements_by_tag_name_ns( 'FPCONTEXTT' ).
IF li_node_collection IS INITIAL.
RETURN.
ENDIF.
li_iterator = li_node_collection->create_iterator( ).
li_node = li_iterator->get_next( ).
WHILE li_node IS NOT INITIAL.
CLEAR lt_contexts.
li_item_list = li_node->get_children( ).
li_items = li_item_list->create_iterator( ).
DO.
li_item = li_items->get_next( ).
IF li_item IS INITIAL.
EXIT.
ENDIF.
CLEAR ls_context.
li_field = li_item->get_first_child( ).
WHILE li_field IS NOT INITIAL.
ls_field-name = li_field->get_name( ).
ls_field-value = li_field->get_value( ).
INSERT ls_field INTO TABLE ls_context-fields.
ASSIGN COMPONENT ls_field-name OF STRUCTURE ls_context TO <lv_value>.
IF sy-subrc = 0.
<lv_value> = ls_field-value.
ENDIF.
li_field = li_field->get_next( ).
ENDWHILE.
INSERT ls_context INTO TABLE lt_contexts.
ENDDO.
SORT lt_contexts BY name state language id.
lv_index = 1.
li_items = li_item_list->create_iterator( ).
DO.
li_item = li_items->get_next( ).
IF li_item IS INITIAL.
EXIT.
ENDIF.
READ TABLE lt_contexts INTO ls_context INDEX lv_index.
li_field = li_item->get_first_child( ).
WHILE li_field IS NOT INITIAL.
READ TABLE ls_context-fields ASSIGNING <ls_field>
WITH KEY name = li_field->get_name( ).
IF sy-subrc = 0.
li_field->set_value( |{ <ls_field>-value }| ).
ENDIF.
li_field = li_field->get_next( ).
ENDWHILE.
lv_index = lv_index + 1.
ENDDO.
li_node = li_iterator->get_next( ).
ENDWHILE.
ENDMETHOD.
METHOD zif_abapgit_object~changed_by.
SELECT SINGLE lastuser FROM fplayout
INTO rv_user
WHERE name = ms_item-obj_name
AND state = 'A'.
IF rv_user IS INITIAL.
SELECT SINGLE firstuser FROM fplayout
INTO rv_user
WHERE name = ms_item-obj_name
AND state = 'A'.
ENDIF.
IF rv_user IS INITIAL.
rv_user = c_user_unknown.
ENDIF.
ENDMETHOD.
METHOD zif_abapgit_object~delete.
DATA: lv_name TYPE fpname.
lv_name = ms_item-obj_name.
TRY.
TRY.
CALL METHOD cl_fp_wb_form=>('DELETE')
EXPORTING
i_name = lv_name
i_ordernum = iv_transport
i_dark = abap_true. " > 740
CATCH cx_sy_dyn_call_error.
cl_fp_wb_form=>delete(
i_name = lv_name
i_ordernum = iv_transport ).
ENDTRY.
CATCH cx_fp_api.
zcx_abapgit_exception=>raise( 'SFPI error, delete' ).
ENDTRY.
ENDMETHOD.
METHOD check_ads_connection.
DATA lv_version TYPE string.
TRY.
lv_version = cl_fp=>get_reference(
)->create_pdf_object( connection = cl_fp=>get_ads_connection( )
)->get_version_info( ).
IF lv_version IS INITIAL.
zcx_abapgit_exception=>raise( 'SFPF: ADS connection not configured' ).
ENDIF.
CATCH cx_root.
zcx_abapgit_exception=>raise( 'SFPF: ADS connection not configured' ).
ENDTRY.
ENDMETHOD.
METHOD zif_abapgit_object~deserialize.
DATA: lv_xstr TYPE xstring,
lv_layout TYPE xstring,
lv_name TYPE fpname,
li_wb_object TYPE REF TO if_fp_wb_form,
li_form TYPE REF TO if_fp_form,
lx_fp_err TYPE REF TO cx_fp_api.
check_ads_connection( ).
lv_name = ms_item-obj_name.
lv_xstr = cl_ixml_80_20=>render_to_xstring( io_xml->get_raw( ) ).
TRY.
li_form = cl_fp_helper=>convert_xstring_to_form( lv_xstr ).
IF mo_files->contains_file( c_layout_file_ext ) = abap_true.
lv_layout = mo_files->read_raw( c_layout_file_ext ).
li_form->get_layout( )->set_layout_data( lv_layout ).
ENDIF.
IF zif_abapgit_object~exists( ) = abap_true.
TRY.
CALL METHOD cl_fp_wb_form=>('DELETE')
EXPORTING
i_name = lv_name
i_ordernum = iv_transport
i_dark = abap_true. " > 740
CATCH cx_sy_dyn_call_error.
cl_fp_wb_form=>delete(
i_name = lv_name
i_ordernum = iv_transport ).
ENDTRY.
ENDIF.
tadir_insert( iv_package ).
TRY.
CALL METHOD cl_fp_wb_form=>('CREATE')
EXPORTING
i_name = lv_name
i_form = li_form
i_ordernum = iv_transport
i_dark = abap_true " > 740
RECEIVING
r_wb_form = li_wb_object.
CATCH cx_sy_dyn_call_error.
li_wb_object = cl_fp_wb_form=>create(
i_name = lv_name
i_form = li_form
i_ordernum = iv_transport ).
ENDTRY.
li_wb_object->save( ).
li_wb_object->free( ).
CATCH cx_fp_api INTO lx_fp_err.
zcx_abapgit_exception=>raise( |SFPF deserialization error: { lx_fp_err->get_text( ) }| ).
ENDTRY.
zcl_abapgit_objects_activation=>add_item( ms_item ).
ENDMETHOD.
METHOD zif_abapgit_object~exists.
DATA: lv_name TYPE fpname.
" Check for any state
SELECT SINGLE name FROM fplayout
INTO lv_name
WHERE name = ms_item-obj_name.
rv_bool = boolc( sy-subrc = 0 ).
ENDMETHOD.
METHOD zif_abapgit_object~get_comparator.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~get_deserialize_order.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~get_deserialize_steps.
APPEND zif_abapgit_object=>gc_step_id-abap TO rt_steps.
ENDMETHOD.
METHOD zif_abapgit_object~get_metadata.
rs_metadata = get_metadata( ).
ENDMETHOD.
METHOD zif_abapgit_object~is_active.
rv_active = is_active( ).
ENDMETHOD.
METHOD zif_abapgit_object~is_locked.
DATA: lv_object TYPE seqg3-garg.
lv_object = |{ ms_item-obj_name }|.
OVERLAY lv_object WITH ' '.
lv_object = lv_object && '*'.
rv_is_locked = exists_a_lock_entry_for( iv_lock_object = 'EFPFORM'
iv_argument = lv_object ).
ENDMETHOD.
METHOD zif_abapgit_object~jump.
" Covered by ZCL_ABAPGIT_OBJECTS=>JUMP
ENDMETHOD.
METHOD zif_abapgit_object~map_filename_to_object.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~map_object_to_filename.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~serialize.
DATA: lv_xstr TYPE xstring,
li_document TYPE REF TO if_ixml_document,
li_node_collection TYPE REF TO if_ixml_node_collection,
li_node_iter TYPE REF TO if_ixml_node_iterator,
li_node TYPE REF TO if_ixml_node,
li_node_new TYPE REF TO if_ixml_node,
li_node_parent TYPE REF TO if_ixml_node.
lv_xstr = form_to_xstring( ).
li_document = cl_ixml_80_20=>parse_to_document( stream_xstring = lv_xstr ).
* Clear CACHE_INFO
li_node_collection = li_document->get_elements_by_tag_name_ns( 'CACHE_INFO' ).
IF li_node_collection IS NOT INITIAL.
li_node_iter = li_node_collection->create_iterator( ).
DO.
li_node = li_node_iter->get_next( ).
IF li_node IS INITIAL.
EXIT.
ENDIF.
li_node_new = li_document->create_element_ns( 'CACHE_INFO' ).
li_node_parent = li_node->get_parent( ).
li_node_parent->replace_child( new_child = li_node_new
old_child = li_node ).
ENDDO.
ENDIF.
fix_oref( li_document ).
sort_contexts( li_document ).
io_xml->set_raw( li_document->get_root_element( ) ).
ENDMETHOD.
ENDCLASS.
|