Press n or j to go to the next uncovered block, b, p or k for the previous block.
| 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 | 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x 1x | CLASS zcl_abapgit_repo_online DEFINITION
PUBLIC
INHERITING FROM zcl_abapgit_repo
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
INTERFACES zif_abapgit_repo_online .
ALIASES get_url FOR zif_abapgit_repo_online~get_url.
ALIASES get_selected_branch FOR zif_abapgit_repo_online~get_selected_branch.
ALIASES set_url FOR zif_abapgit_repo_online~set_url.
ALIASES select_branch FOR zif_abapgit_repo_online~select_branch.
ALIASES get_selected_commit FOR zif_abapgit_repo_online~get_selected_commit.
ALIASES get_current_remote FOR zif_abapgit_repo_online~get_current_remote.
ALIASES select_commit FOR zif_abapgit_repo_online~select_commit.
ALIASES switch_origin FOR zif_abapgit_repo_online~switch_origin.
ALIASES get_switched_origin FOR zif_abapgit_repo_online~get_switched_origin.
ALIASES push FOR zif_abapgit_repo_online~push.
ALIASES create_branch FOR zif_abapgit_repo_online~create_branch.
ALIASES check_for_valid_branch FOR zif_abapgit_repo_online~check_for_valid_branch.
ALIASES get_remote_settings FOR zif_abapgit_repo_online~get_remote_settings.
METHODS zif_abapgit_repo~get_files_remote
REDEFINITION .
METHODS zif_abapgit_repo~get_name
REDEFINITION .
METHODS zif_abapgit_repo~has_remote_source
REDEFINITION .
METHODS constructor
IMPORTING
is_data TYPE zif_abapgit_persistence=>ty_repo.
PROTECTED SECTION.
PRIVATE SECTION.
DATA mt_objects TYPE zif_abapgit_definitions=>ty_objects_tt .
DATA mv_current_commit TYPE zif_abapgit_git_definitions=>ty_sha1 .
METHODS handle_stage_ignore
IMPORTING
!io_stage TYPE REF TO zcl_abapgit_stage
RAISING
zcx_abapgit_exception .
METHODS set_objects
IMPORTING
!it_objects TYPE zif_abapgit_definitions=>ty_objects_tt
RAISING
zcx_abapgit_exception .
METHODS fetch_remote
RAISING
zcx_abapgit_exception .
METHODS get_objects
RETURNING
VALUE(rt_objects) TYPE zif_abapgit_definitions=>ty_objects_tt
RAISING
zcx_abapgit_exception .
METHODS raise_error_if_branch_exists
IMPORTING
iv_name TYPE string
RAISING
zcx_abapgit_exception.
ENDCLASS.
CLASS zcl_abapgit_repo_online IMPLEMENTATION.
METHOD constructor.
super->constructor( is_data ).
ENDMETHOD.
METHOD fetch_remote.
DATA: li_progress TYPE REF TO zif_abapgit_progress,
ls_pull TYPE zcl_abapgit_git_porcelain=>ty_pull_result.
IF mv_request_remote_refresh = abap_false.
RETURN.
ENDIF.
li_progress = zcl_abapgit_progress=>get_instance( 1 ).
li_progress->show( iv_current = 1
iv_text = 'Fetch remote files' ).
IF get_selected_commit( ) IS INITIAL.
ls_pull = zcl_abapgit_git_porcelain=>pull_by_branch( iv_url = get_url( )
iv_branch_name = get_selected_branch( ) ).
ELSE.
ls_pull = zcl_abapgit_git_porcelain=>pull_by_commit( iv_url = get_url( )
iv_commit_hash = get_selected_commit( ) ).
ENDIF.
set_files_remote( ls_pull-files ).
set_objects( ls_pull-objects ).
mv_current_commit = ls_pull-commit.
ENDMETHOD.
METHOD get_objects.
fetch_remote( ).
rt_objects = mt_objects.
ENDMETHOD.
METHOD handle_stage_ignore.
DATA: lv_add TYPE abap_bool,
lo_dot_abapgit TYPE REF TO zcl_abapgit_dot_abapgit,
lt_stage TYPE zif_abapgit_definitions=>ty_stage_tt.
FIELD-SYMBOLS: <ls_stage> LIKE LINE OF lt_stage.
lo_dot_abapgit = get_dot_abapgit( ).
lt_stage = io_stage->get_all( ).
LOOP AT lt_stage ASSIGNING <ls_stage> WHERE method = zif_abapgit_definitions=>c_method-ignore.
lo_dot_abapgit->add_ignore(
iv_path = <ls_stage>-file-path
iv_filename = <ls_stage>-file-filename ).
" remove it from the staging object, as the action is handled here
io_stage->reset( iv_path = <ls_stage>-file-path
iv_filename = <ls_stage>-file-filename ).
lv_add = abap_true.
ENDLOOP.
IF lv_add = abap_true.
io_stage->add(
iv_path = zif_abapgit_definitions=>c_root_dir
iv_filename = zif_abapgit_definitions=>c_dot_abapgit
iv_data = lo_dot_abapgit->serialize( ) ).
set_dot_abapgit( lo_dot_abapgit ).
ENDIF.
ENDMETHOD.
METHOD raise_error_if_branch_exists.
DATA:
lt_branches TYPE zif_abapgit_git_definitions=>ty_git_branch_list_tt,
lv_display_name TYPE string.
lt_branches = zcl_abapgit_git_factory=>get_git_transport(
)->branches( get_url( )
)->get_branches_only( ).
READ TABLE lt_branches WITH TABLE KEY name_key
COMPONENTS name = iv_name
TRANSPORTING NO FIELDS.
IF sy-subrc = 0.
lv_display_name = zcl_abapgit_git_branch_utils=>get_display_name( iv_name ).
zcx_abapgit_exception=>raise( |Branch '{ lv_display_name }' already exists| ).
ENDIF.
ENDMETHOD.
METHOD set_objects.
mt_objects = it_objects.
ENDMETHOD.
METHOD zif_abapgit_repo_online~check_for_valid_branch.
DATA:
li_branch_list TYPE REF TO zif_abapgit_git_branch_list,
lx_error TYPE REF TO zcx_abapgit_exception,
lv_branch TYPE string,
lv_head TYPE string,
lv_msg TYPE string.
lv_branch = get_selected_branch( ).
IF lv_branch IS NOT INITIAL.
li_branch_list = zcl_abapgit_git_factory=>get_git_transport( )->branches( get_url( ) ).
TRY.
li_branch_list->find_by_name( lv_branch ).
CATCH zcx_abapgit_exception INTO lx_error.
" branch does not exist, fallback to head
lv_head = li_branch_list->get_head_symref( ).
lv_msg = |{ lx_error->get_text( ) }. Switched to { zcl_abapgit_git_branch_utils=>get_display_name( lv_head ) }|.
MESSAGE lv_msg TYPE 'S'.
select_branch( lv_head ).
ENDTRY.
ENDIF.
ENDMETHOD.
METHOD zif_abapgit_repo_online~create_branch.
DATA: lv_sha1 TYPE zif_abapgit_git_definitions=>ty_sha1.
ASSERT iv_name CP zif_abapgit_git_definitions=>c_git_branch-heads.
IF iv_from IS INITIAL.
lv_sha1 = get_current_remote( ).
ELSE.
lv_sha1 = iv_from.
ENDIF.
raise_error_if_branch_exists( iv_name ).
zcl_abapgit_git_porcelain=>create_branch(
iv_url = get_url( )
iv_name = iv_name
iv_from = lv_sha1 ).
" automatically switch to new branch
select_branch( iv_name ).
ENDMETHOD.
METHOD zif_abapgit_repo_online~get_current_remote.
fetch_remote( ).
rv_sha1 = mv_current_commit.
ENDMETHOD.
METHOD zif_abapgit_repo_online~get_remote_settings.
DATA lv_branch TYPE string.
rs_settings-url = get_url( ).
rs_settings-offline = abap_false.
rs_settings-switched_origin = get_switched_origin( ).
IF get_selected_commit( ) IS NOT INITIAL.
rs_settings-commit = get_selected_commit( ).
rs_settings-branch = get_selected_branch( ).
rs_settings-head_type = zif_abapgit_git_definitions=>c_head_types-commit.
ELSEIF get_switched_origin( ) IS NOT INITIAL.
" get_switched_origin( ) returns the original repo url + HEAD concatenated with @
" get_branch( ) returns the branch of the PR in the source repo
" get_url( ) returns the source repo of the PR branch
rs_settings-switched_origin = get_switched_origin( ).
SPLIT rs_settings-switched_origin AT '@' INTO rs_settings-url rs_settings-branch.
IF rs_settings-branch CP zif_abapgit_git_definitions=>c_git_branch-tags.
rs_settings-tag = rs_settings-branch.
CLEAR rs_settings-branch.
ENDIF.
lv_branch = get_selected_branch( ).
REPLACE FIRST OCCURRENCE OF zif_abapgit_git_definitions=>c_git_branch-heads_prefix IN lv_branch WITH space.
CONDENSE lv_branch.
rs_settings-pull_request = |{ get_url( ) }@{ lv_branch }|.
rs_settings-head_type = zif_abapgit_git_definitions=>c_head_types-pull_request.
ELSE.
rs_settings-branch = get_selected_branch( ).
rs_settings-head_type = zif_abapgit_git_definitions=>c_head_types-branch.
IF rs_settings-branch CP zif_abapgit_git_definitions=>c_git_branch-tags.
rs_settings-head_type = zif_abapgit_git_definitions=>c_head_types-tag.
rs_settings-tag = rs_settings-branch.
CLEAR rs_settings-branch.
ENDIF.
ENDIF.
ENDMETHOD.
METHOD zif_abapgit_repo_online~get_selected_branch.
rv_name = ms_data-branch_name.
ENDMETHOD.
METHOD zif_abapgit_repo_online~get_selected_commit.
rv_selected_commit = ms_data-selected_commit.
ENDMETHOD.
METHOD zif_abapgit_repo_online~get_switched_origin.
rv_switched_origin = ms_data-switched_origin.
ENDMETHOD.
METHOD zif_abapgit_repo_online~get_url.
rv_url = ms_data-url.
ENDMETHOD.
METHOD zif_abapgit_repo_online~push.
* assumption: PUSH is done on top of the currently selected branch
DATA: ls_push TYPE zcl_abapgit_git_porcelain=>ty_push_result,
lv_text TYPE string,
lv_parent TYPE zif_abapgit_git_definitions=>ty_sha1.
IF ms_data-branch_name CP zif_abapgit_git_definitions=>c_git_branch-tags.
lv_text = |You're working on a tag. Currently it's not |
&& |possible to push on tags. Consider creating a branch instead|.
zcx_abapgit_exception=>raise( lv_text ).
ENDIF.
IF ms_data-selected_commit IS NOT INITIAL.
lv_text = 'You are currently checked out in a commit.'.
lv_text = |{ lv_text } You must be on a branch to push|.
zcx_abapgit_exception=>raise( lv_text ).
ENDIF.
IF ms_data-local_settings-block_commit = abap_true
AND zcl_abapgit_code_inspector=>get_code_inspector( get_package( )
)->is_successful( ) = abap_false.
zcx_abapgit_exception=>raise( |A successful code inspection is required| ).
ENDIF.
handle_stage_ignore( io_stage ).
IF get_selected_commit( ) IS INITIAL.
lv_parent = get_current_remote( ).
ELSE.
lv_parent = get_selected_commit( ).
ENDIF.
ls_push = zcl_abapgit_git_porcelain=>push(
is_comment = is_comment
io_stage = io_stage
iv_branch_name = get_selected_branch( )
iv_url = get_url( )
iv_parent = lv_parent
it_old_objects = get_objects( ) ).
set_objects( ls_push-new_objects ).
set_files_remote( ls_push-new_files ).
mv_current_commit = ls_push-branch.
checksums( )->update( ls_push-updated_files ).
ENDMETHOD.
METHOD zif_abapgit_repo_online~select_branch.
reset_remote( ).
set( iv_branch_name = iv_branch_name
iv_selected_commit = space ).
ENDMETHOD.
METHOD zif_abapgit_repo_online~select_commit.
reset_remote( ).
set( iv_selected_commit = iv_selected_commit ).
ENDMETHOD.
METHOD zif_abapgit_repo_online~set_url.
reset_remote( ).
set( iv_url = iv_url ).
ENDMETHOD.
METHOD zif_abapgit_repo_online~switch_origin.
DATA lv_offs TYPE i.
" For repo settings page
IF iv_overwrite = abap_true.
set( iv_switched_origin = iv_url ).
RETURN.
ENDIF.
IF iv_url IS INITIAL.
IF ms_data-switched_origin IS INITIAL.
RETURN.
ELSE.
lv_offs = find(
val = reverse( ms_data-switched_origin )
sub = '@' ).
IF lv_offs = -1.
zcx_abapgit_exception=>raise( 'Incorrect format of switched origin' ).
ENDIF.
lv_offs = strlen( ms_data-switched_origin ) - lv_offs - 1.
set_url( substring(
val = ms_data-switched_origin
len = lv_offs ) ).
select_branch( substring(
val = ms_data-switched_origin
off = lv_offs + 1 ) ).
set( iv_switched_origin = '' ).
ENDIF.
ELSEIF ms_data-switched_origin IS INITIAL.
set( iv_switched_origin = ms_data-url && '@' && ms_data-branch_name ).
set_url( iv_url ).
select_branch( iv_branch ).
ELSE.
zcx_abapgit_exception=>raise( 'Cannot switch origin twice' ).
ENDIF.
ENDMETHOD.
METHOD zif_abapgit_repo~get_files_remote.
fetch_remote( ).
rt_files = super->get_files_remote(
ii_obj_filter = ii_obj_filter
iv_ignore_files = iv_ignore_files ).
ENDMETHOD.
METHOD zif_abapgit_repo~get_name.
rv_name = super->get_name( ).
IF rv_name IS INITIAL.
TRY.
rv_name = zcl_abapgit_url=>name( ms_data-url ).
rv_name = cl_http_utility=>unescape_url( rv_name ).
CATCH zcx_abapgit_exception.
rv_name = 'New online repo'. "unlikely fallback
ENDTRY.
ENDIF.
ENDMETHOD.
METHOD zif_abapgit_repo~has_remote_source.
rv_yes = abap_true.
ENDMETHOD.
ENDCLASS.
|